#!/usr/bin/awk -f

# Copyright 2023 Ted Clark
#
# This program is free software; you can redistribute it and/or modify it under
# the terms of the GNU General Public License, version 2, as published by the Free
# Software Foundation.
#
# This program is distributed in the hope that it will be useful, but WITHOUT ANY
# WARRANTY; without even the implied warranty of MERCHANTABILITY or FITNESS FOR A
# PARTICULAR PURPOSE. See the GNU General Public License for more details.
#
# You should have received a copy of the GNU General Public License along with
# this program; if not, write to the Free Software Foundation, Inc.,
# 59 Temple Place, Suite 330, Boston, MA 02111-1307 USA.

function assert_head()
{
	if (!document_head) {
		print "Missing document head" > "/dev/stderr"
		do_end = 0
		exit(1)
	}
}

function close_tags()
{
	switch (state) {
	case "QUOTE":
	case "QUOTE2":
		print "</blockquote>"
		break
	case "TD":
	case "TD2":
	case "TH":
	case "TH2":
		print "</tr>"
		break
	case "ULIST":
	case "ULIST2":
		print "</ul>"
		break
	}
}

function decode_string(string)
{
	decoded_str = ""
	skip = 0

	for (ii = 1; ii <= length(string); ii++) {
		if (skip) {
			# Skip over HTML codes and tags
			skip--
			continue
		}
		if (substr(string, ii, 1) == "&") {
			# Replace '&' with &amp;, but don't change HTML codes such as &nbsp;
			# to &amp;nbsp;.
			codes[1] = "&#45;"
			codes[2] = "&#x2713;"
			codes[3] = "&amp;"
			codes[4] = "&epsilon;"
			codes[5] = "&gt;"
			codes[6] = "&lt;"
			codes[7] = "&mdash;"
			codes[8] = "&nbsp;"
			codes[9] = "&ndash;"
			found = 0

			for (j = 1; j <= length(codes); j++) {
				if (substr(string, ii, length(codes[j])) == codes[j]) {
					decoded_str = decoded_str codes[j]
					skip = length(codes[j]) - 1
					found = 1
					break
				}
			}
			if (found) {
				continue
			}
			decoded_str = decoded_str "&amp;"
		}
		else if (substr(string, ii, 1) == "<") {
			# Replace '<' with &lt;, but don't change HTML tags such as <br>
			# to &lt;br>.
			tags[1] = "<br>"
			tags[2] = "<code>"
			tags[3] = "</code>"
			tags[4] = "<del>"
			tags[5] = "</del>"
			tags[6] = "<em>"
			tags[7] = "</em>"
			tags[8] = "<i>"
			tags[9] = "</i>"
			tags[10] = "<ins>"
			tags[11] = "</ins>"
			tags[12] = "<p>"
			tags[13] = "</p>"
			tags[14] = "<pre>"
			tags[15] = "</pre>"
			tags[16] = "<span>"
			tags[17] = "</span>"
			tags[18] = "<strong>"
			tags[19] = "</strong>"
			tags[20] = "<sup>"
			tags[21] = "</sup>"
			found = 0

			for (j = 1; j <= length(tags); j++) {
				if (substr(string, ii, length(tags[j])) == tags[j]) {
					decoded_str = decoded_str tags[j]
					skip = length(tags[j]) - 1
					found = 1
					break
				}
			}
			if (found) {
				continue
			}
			decoded_str = decoded_str "&lt;"
		}
		else if (substr(string, ii, 1) == ">") {
			decoded_str = decoded_str "&gt;"
		}
		else {
			decoded_str = decoded_str substr(string, ii, 1)
		}
	}
	return decoded_str
}

function is_numeric(string)
{
	# Give the loop control variable a unique name so that it doesn't
	# conflict with any variables in the calling function. (Awk does not
	# have block scope.)
	for (is_numeric_i = 1; is_numeric_i <= length(string); is_numeric_i++) {
		if (substr(string, is_numeric_i, 1) < "0" || substr(string, is_numeric_i, 1) > "9") {
			return 0
		}
	}
	return 1
}

function is_table_state()
{
	if (state == "TD" || state == "TD2" || state == "TH" || state == "TH2") {
		return 1
	}
	return 0
}

function print_css(line)
{
	if (!in_css) {
		print "<style>"
		in_css = 1
	}
	print line
}

function print_data(colspan, rowspan, td_class, data)
{
	td = "\t<td"
	if (colspan) {
		td = td sprintf(" colspan=\"%d\"", colspan)
	}
	if (rowspan) {
		td = td sprintf(" rowspan=\"%d\"", rowspan)
	}
	# Data class overrides header class
	if (td_class && th_class[th_column]) {
		if (td_class == "demark" && th_class[th_column] == "code") {
			td = td " class=\"demarkcode\""
		}
		else if (td_class == "mark" && th_class[th_column] == "code") {
			td = td " class=\"markcode\""
		}
		else if (td_class == "nocode" && th_class[th_column] == "code") {
			# no-op
		}
		else {
			td = td sprintf(" class=\"%s\"", td_class)
		}
	}
	else if (td_class) {
		td = td sprintf(" class=\"%s\"", td_class)
	}
	else if (th_class[th_column]) {
		td = td sprintf(" class=\"%s\"", th_class[th_column])
	}
	td = td sprintf(">%s</td>", data)
	print td
}

function print_document_head(line)
{
	if (!document_title) {
		# The first non-blank line is the page title.
		if (length(line) == 0) {
			return
		}
		print "<html lang=\"en\">"
		print "<head>"
		printf "<title>%s</title>\n", line
		print "<meta charset=\"utf-8\">"
		document_title = 1
	}
	else if (substr(line, length(line) - 3) == ".css") {
		printf "<link rel=\"stylesheet\" type=\"text/css\" href=\"%s\">\n", line
	}
}

function print_hyperlink(line)
{
	split(line, parts, "\t")
	if (length(parts) != 2) {
		print "Malformed link" > "/dev/stderr"
		do_end = 0
		exit(1)
	}
	printf "<p><a href=\"%s\">%s</a></p>\n", parts[1], parts[2]
}

function print_quote(line)
{
	if (state == "QUOTE") {
		print "<blockquote>"
		state = "QUOTE2"
	}
	printf "\t<p class=\"quote\">%s</p>\n", line
}

function print_td(line)
{
	if (!in_table) {
		print "<table>"
		in_table = 1
	}
	if (state == "TD") {
		print "<tr>"
		th_column = 1
		state = "TD2"
	}
	# Blank lines are used as placeholders for colspan and rowspan. If they
	# are not used, then th_column will be off.
	if (length(line)) {
		line = decode_string(line)
		colspan = 0
		rowspan = 0
		td_class = ""
		data = ""
		# Set flag when data is found. Testing 'data' for an empty
		# string doesn't work, since awk conflates an empty string with
		# null, and some valid data are empty strings.
		data_found = 0
		if (index(line, "\t")) {
			split(line, parts, "\t")
			data = parts[1]
			data_found = 1

			for (i = 2; i <= length(parts); i++) {
				if (substr(parts[i], 1, 1) == "c") {
					s = substr(parts[i], 2)
					if (is_numeric(s)) {
						colspan = int(s)
					}
				}
				else if (substr(parts[i], 1, 1) == "r") {
					s = substr(parts[i], 2)
					if (is_numeric(s)) {
						rowspan = int(s)
					}
				}
				else {
					td_class = parts[i]
				}
			}
		}
		print_data(colspan, rowspan, td_class, data_found ? data : line)
	}
	# Increment th_column *after* print_data is called.
	th_column++
}

function print_text(line)
{
	gsub("--", "\\&mdash;", line)
	if (paragraph_num) {
		printf "<p><span class=\"pnum\">&para;%d</span> %s</p>\n", paragraph_num, line
		paragraph_num++
	}
	else {
		printf "<p>%s</p>\n", line
	}
}

function print_th(line)
{
	if (!in_table) {
		print "<table>"
		in_table = 1
	}
	if (state == "TH") {
		print "<tr>"
		delete th_class
		th_column = 1
		state = "TH2"
	}
	if (index(line, "\t")) {
		split(line, parts, "\t")
		if (length(parts) != 2) {
			print "Error parsing header" > "/dev/stderr"
			do_end = 0
			exit(1)
		}
		th_class[th_column++] = parts[2]
		printf "\t<th>%s</th>\n", parts[1]
	}
	else {
		th_class[th_column++] = ""
		printf "\t<th>%s</th>\n", line
	}
}

function print_ulist(line)
{
	if (state == "ULIST") {
		print "<ul>"
		state = "ULIST2"
	}
	printf "\t<li>%s</li>\n", line
}

function rtrim(string)
{
	sub(/[ \t\n\r]+$/, "", string)
	return string
}

BEGIN {
	do_end = 1
	document_head = 0
	document_title = 0
	in_css = 0
	in_table = 0
	matched = 0
	paragraph_num = 0
	state = "NO_OP"
	# Declare th_class as a 1-element array, and then delete that element.
	th_class[1]
	delete th_class
	th_column = 0

	if (ARGC != 2) {
		print "Usage: metadoc FILENAME" > "/dev/stderr"
		do_end = 0
		exit(1)
	}
	print "<!doctype html>"
}

/^---$/ {
	close_tags()
	state = "NO_OP"
	matched = 1
}

/^---body$/ {
	if (in_css) {
		print "</style>"
		in_css = 0
	}
	if (!document_head) {
		print "</head>\n<body>"
		document_head = 1
	}
	state = "NO_OP"
	matched = 1
}

/^---br$/ {
	assert_head()
	# ---br does not close tags or change state, so table rows and tables
	# have to be explicitly closed.
	if (in_table) {
		print "</tr>\n</table>"
		in_table = 0
		state = "NO_OP"
	}
	print "<br>"
	matched = 1
}

/^---c$/ {
	close_tags()
	state = "COMMENT"
	matched = 1
}

/^---css$/ {
	state = "CSS"
	matched = 1
}

/^---h1$/ {
	assert_head()
	close_tags()
	state = "H1"
	matched = 1
}

/^---h2$/ {
	assert_head()
	close_tags()
	state = "H2"
	matched = 1
}

/^---head$/ {
	state = "HEAD"
	matched = 1
}

/^---l$/ {
	assert_head()
	close_tags()
	state = "LINK"
	matched = 1
}

/^---pnum$/ {
	paragraph_num = 1
	matched = 1
}

/^---q$/ {
	assert_head()
	close_tags()
	state = "QUOTE"
	matched = 1
}

/^---raw$/ {
	assert_head()
	close_tags()
	state = "RAW"
	matched = 1
}

/^---t$/ {
	assert_head()
	close_tags()
	state = "TEXT"
	matched = 1
}

/^---td$/ {
	assert_head()
	close_tags()
	state = "TD"
	matched = 1
}

/^---th$/ {
	assert_head()
	close_tags()
	state = "TH"
	matched = 1
}

/^---ul$/ {
	assert_head()
	close_tags()
	state = "ULIST"
	matched = 1
}

!matched {
	# Don't trim the left side -- leading tabs are metadata
	line = rtrim($0)
	if (length(line) == 0 && state != "CSS" && state != "RAW" && !is_table_state()) {
		next
	}
	if (in_table && !is_table_state()) {
		print "</table>"
		in_table = 0
	}

	switch (state) {
	case "COMMENT":
		printf "<!-- %s -->\n", line
		break
	case "CSS":
		print_css(line)
		break
	case "H1":
		printf "<h1>%s</h1>\n", line
		break
	case "H2":
		printf "<h2>%s</h2>\n", line
		break
	case "HEAD":
		print_document_head(line)
		break
	case "LINK":
		print_hyperlink(line)
		break
	case "NO_OP":
		# no-op
		break
	case "QUOTE":
	case "QUOTE2":
		print_quote(line)
		break
	case "RAW":
		print line
		break
	case "TD":
	case "TD2":
		print_td(line)
		break
	case "TEXT":
		print_text(line)
		break
	case "TH":
	case "TH2":
		print_th(line)
		break
	case "ULIST":
	case "ULIST2":
		print_ulist(line)
		break
	default:
		printf "Unknown state: %s\n", state > "/dev/stderr"
		exit(1)
	}
}

{
	matched = 0
}

END {
	if (do_end) {
		if (in_table) {
			print "</table>"
		}
		if (document_head) {
			print "</body>\n</html>"
		}
	}
}